Heya guys!!  Here is a new compilation of Death Knight macros for your macro fiending needs!!

Many macros can be altered to work for other abilities and/or needs.  Just make sure you test them if you change them.

Also due to weird HTML copy/paste issues, I’ve reset all macros into the <code> setting through HTML.  That should resolve any cut/paste issues.

Macros

Ghoulachoo, I choose you!!
#showtooltip
/cast [target=target,exists,harm] Leap
/cast [target=target,harm] Gnaw
/stopmacro [target=target,harm]
/cast [target=target,exists,noharm] Leap
/stopmacro [target=target,exists,noharm]
/cast [target=player] Leap
/petfollow

• Targeting an enemy:  Leap to them and then stun them.
• Targeting no one:  Leap to you and follow you.
• Targeting another player:  Leap to them, like getting them to a healer or away from whomever is hitting them.

Mastery over death!!!
#showtooltip
/cast [target=pet,exists,nomodifier:shift,nodead] Death Pact; [modifier:shift] Raise Ally; Raise Dead

• Death Pact if you have a pet up.
• Click + Shift to Raise Ally.
• Summon ghoul if you have no pet up.

I’m in.  I’m out.  I’m in.  I’m out.
/cast [modifier: alt] Frost Presence; [modifier: shift] Unholy Presence; [nomodifier] Blood Presence

• Click to swap to Blood Presence
• Click + Shift to swap to Unholy Presence
• Click + Alt to swap to Frost Presence

Shifty Ghouls…
#showtooltip Gnaw
/cast [nomodifier] leap
/cast [nomodifier] gnaw
/cast [modifier:shift,target=focus] leap
/cast [modifier:shift,target=focus] gnaw

• This will make your ghoul leap to a target and stun it.
• By holding down the SHIFT key it will instead leap and stun your Focus target without making you change your current target.

DIE DIE DIE DIE!!!
/startattack
/petattack

• This (when added to any existing macro) will turn your auto-attack on and make your pet attack.  Either line can be removed or added to any macro.
• If you do not have a target, this will make you select a nearby target for auto attack per the Blizzard default targeting system.  Typically this is the nearest mob.

My sword is bigger than yours… o.O
#showtooltip
/Cast Empower Rune Weapon
/Cast Death Coil
/Cast Rune Strike

• You can replace DC also with Frost Strike.
• ERW and RS do not take up a GCD, but you usually lose 1 second due to real life clicking.  Why not work a DC or FS into that lost time?

Whatcha want me to kill?
/assist (name)
/startattack
/petattack

• Replace (name) with a player’s name whom you wish to assist in combat.
• You will target the player’s target, start auto-attacking their target, and send your pet to attack their target.
• If the player is not there, this will still attack your current target.

Get over here!!
#showtooltip Death Grip
/cast Death Grip
/cast Chains of Ice

• This is your anti-runner macro.  Double tap to cast both spells.
• If DG is on CD, this will still cast CoI.

Willy, Willy, get this bitch off me!!
#showtooltip Hungering Cold
/cast Lichborne
/cast Anti-Magic Shell
/cast Hungering Cold
/cast Unbreakable Armor
/cast Icebound Fortitude
/cast [target=player] Death Coil
/run UIErrorsFrame:Clear()

• This is your “holy crap I’m gonna die” macro for Frost PvP.  It spams all of your defensive CD’s while using your CC as well.
• If you have Runic Power available, and Lichborne was available, it will heal you with Death Coils.

Two DC’s for you, one DC for Bubba…
#showtooltip Death Coil
/cast [nomodifier] Death Coil; [modifier:alt,target=pet] Death Coil

• Click this and it fires DC off at your target.
• Press ALT and when clicking it and it hits your Ghoul with DC for a heal without losing your current target.
• Bubba is your ghoul fyi. 

Death Coils for EVERYONE!!!
#showtooltip Death Coil
/cast [nomodifier] Death Coil
/cast [modifier:shift, target=mouseover] Death Coil

• Casts DC on target.
• Click + Shift casts DC on your mouse over target.

Shifty Corpses need explodin’!!
#showtooltip
/cast [modifier:shift,target=pet] Corpse Explosion
/targetlasttarget
/cast [nomodifier] Corpse Explosion

• If your last target was killed it will target the corpse and cast Corpse Explosion
• Holding down Shift when clicking this macro will instead cast CE on your ghoul.

BOOM MOTHA!@#$A!!!
#showtooltip Corpse Explosion
/cast [target=pet] Corpse Explosion


• Simple and easy, explodes your pet without changing your target.

Is it cold in here?
#showtooltip Howling Blast
/cast Deathchill
/cast Howling Blast

• PvP Frost burst macro for HB.

Did you seriously just strangle a mouse?
/cast [target=mouseover] Strangulate

• Cast Strangulate on whatever target you are hovering your mouse over.

Lazy mode on:  Rune Strike SPAM please!?!?!!
#showtooltip Icy Touch
/cast Rune Strike
/cast Icy Touch

• You can swap out any attack with “Icy Touch” to tie Rune Strike to that attack.
• This will fire off RS if it is available and you have enough RP when you click the macro.

Quit casting Horn of Winter you !@#$!!!!
/cancelaura Horn of Winter
/cast Horn of Winter

• Cancels HoW buff on yourself and then casts HoW.
• Useful when grouped with someone with a higher level HoW or a longer duration HoW.

Cool as Ice!!
#showtooltip chains of ice
/cast [target=focus, exists] chains of ice; chains of ice

• This will cast CoI on your Focus target, or your regular target if you do not have a Focus target.

Oh no you don’t!!
#showtooltip death grip
/cast [target=focus, exists] death grip; death grip

• This will cast DG on your Focus target, or your regular target if you do not have a Focus target.

STFU!!
#showtooltip strangulate
/cast [target=focus, exists] strangulate; strangulate

• This will cast Strangulate on your Focus target, or your regular target if you do not have a Focus target.

HEALZ MY PET ZOMG!!!!
/cast [target=pet] Death Coil

• Keep your current target, but still throw a DC heal at your ghoul.

GET OVER HERE AND PAY ATTENTION TO ME!!!  /needy
#showtooltip Dark Command
/cast [nomodifier] Dark Command; [modifier:alt] Death Grip

• Taunt the target to you.
• Death Grip the target to you by holding down ALT.

Lazy mode IT/PS + Blood Runes
#showtooltip
/castsequence reset=target/dead Icy Touch, Plague Strike, Blood Strike, Blood Strike

• Places diseases up and then fires off two Blood Strikes to get your Death Runes coming.

Rogues?!?!  Who needs Rogues, lolololol!!
#showtooltip Death Grip
/cast Death Grip
/cast Gnaw

• DG’s your target.
• Ghoul casts stun on your target.
• Make sure you do not have Leap set to auto cast or the ghoul could leap to where the target was before the DG.

Silly kids, brains are for ghouls!!
#showtooltip Ghoul Frenzy
/cast Blood Tap
/stopcasting
/cast Ghoul Frenzy
/run if (UnitBuff("pet","Ghoul Fenzy") and UnitBuff("player","Blood Tap")) then CancelUnitBuff("player","Blood Tap") end

• Casts Ghoul Fenzy by using Blood Tap.
• You should use this macro after all runes are on CD and you’ve just used your Death Runes for something.

POWER UP ACTIVE!!
#showtooltip Unbreakable Armor
/cast Blood Tap
/stopcasting
/cast Unbreakable Armor
/run if (UnitBuff("player","Unbreakable Armor") and UnitBuff("player","Blood Tap")) then CancelUnitBuff("player","Blood Tap") end

• Casts Unbreakable Armor by using Blood Tap.
• Can substitute “Unbreakable Armor” with any ability (such as Bone Shield) to use BT to cast that ability as well.
• You should use this macro after all runes are on CD and you just used your Death Runes for something.

Super Healzorz ZOMG!!!
#showtooltip
/cast Vampiric Blood
/cast Rune Tap

• Pop off VB for extra healing, followed by a suped-up RT heal!!

When RT just won’t cut it because that brown stuff hit the proverbial fan…
#showtooltip Lichborne
/cast Anti-Magic Shell
/cast Icebound Fortitude
/cast Vampiric Blood
/cast Rune Tap
/cast Lichborne
/cast [target=player] Death Coil

• Requires Blood spec, sub-Frost.  This is a reliable way to keep yourself alive no matter what is focused on you.
• Pops all defensive CD’s and uses DC’s to heal yourself.

Frost Lazy Mode, zomg!!
#showtooltip
/castsequence reset=target/dead Icy Touch, Plague Strike, Obliterate, Blood Strike, Pestilence, Frost Strike, Frost Strike

• Opening sequence for a Frost spec.

I’ve got your target right here…
/raid Kill in descending order:
/raid {skull}=Kill first whenever it appears.
/raid {star}
/raid {circle}
/raid {diamond}
/raid {triangle}
/raid {moon}=Sheep
/raid {square}=Sap

• Lists the kill order and CC required for each target.  Symbols can be moved, and assignments can be altered.
• Names of players can be added in to assign tanks or CC’ers to their symbol for easy repetition if people ask or forget.
• /raid can be changed to other formats such as /party.

I marked you.
#showtooltip Mark of Blood
/cast [target=mouseover, exists] Mark of Blood; Mark of Blood

• Cast Mark of Blood on your mouse over target
• If no mouse over target, casts on current target.

Blood Lazy Mode, zomg!!
#showtooltip
/castsequence reset=target/dead Icy Touch, Plague Strike, Heart Strike, Heart Strike, Death Strike, Death Coil

• Opening sequence for a Blood spec.

One button heaven.
#showtooltip
/cast Scourge Strike
/startattack
/petattack
/cast Rune Strike

• You can replace SS with DS or OB depending on your spec.
• This will always start your auto-attack (even if runes are not up).
• This will send your pet after your target.
• This will cast Rune Strike for you if it procs.

You got agro…again…
#showtooltip Dark Command
/w [target=target's target] WATCH YOUR ****ING AGGRO!!!
/cast Dark Command

• Taunts your target and whispers the target’s target the assigned message.

HYSTERIA I TELL YOU!!!  It’s hysteria!!!
#showtooltip
/cast [target=focus, help, nodead] Hysteria

• Makes your target your focus
• Casts Hysteria on your focus.

Unholy Lazy Mode, zomgx2!!!
#showtooltip
/castsequence reset=target/dead Icy Touch, Plague Strike, Blood Strike, Blood Strike, Scourge Strike, Death Coil, Horn of Winter


• Opening sequence for an Unholy spec.

I can’t see…  /cry
/script SetCVar("cameraDistanceMax",30)

• So far away now everyone looks like an ant…  Cool!!
• This changes the distance of your camera view.  Tweaking the number offers results not covered by SJ.

I’ve seriously gotta heal myself?  I’m a Death Knight.  Do you see “healer bitch” in there somewhere?
#showtooltip Lichborne
/cast !Lichborne;
/cast [target=player] Death Coil
/run UIErrorsFrame:Clear()

• Requires Frost sub-spec.
• This allows you to heal yourself with DC’s when Lichborne is available.

Death Grip Sparks!!  Please?
#showtooltip Death Grip
/targetexact Power Spark
/cast Death Grip

• This will Death Grip any target that you are on currently unless there is a Power Spark nearby (Malygos).
• This will never “accidentally” DG Maly possibly causing a wipe.  It will only DG the Power Spark.  The target name can be replaced with any name.

• This will mark any Power Spark in range (so long as you are promoted) with a Skull.  The number can be altered from 1-8.  1 is the Star, 8 is the Skull, and you can figure the rest out from there.
• By swapping the target name you can mark any target with a symbol, such as the NPC’s in the ice cubes at Hodir.
• By removing the “/target Power Spark” line, it will simply mark your current target with a Skull.  This macro will then retarget your last target.

Best mount macro EVAR!!!!!!!!
/run if IsMounted()then return end local t if((GetRealZoneText()=="Dalaran") and (GetSubZoneText() ~="Krasus' Landing") or (GetZoneText()=="Wintergrasp") or not IsFlyableArea()) then t={1} else t={2} end CallCompanion("MOUNT",t[random(#t)])
/dismount

• This will allow you to use one button to mount up where ever you are based upon the “flight restrictions” in that area/zone.
• No more multiple buttons, this does both ground and air mounts in one.
• Please note the 1 and the 2 in the macro need to be adjusted depending on how many mounts you have.  Check your mount window in game.  1 would be the first mount, 2 would be the second mount, and so on.
• If you’re favorite ground mount was the 7th mount, and your favorite aerial mount was the 34th mount, you’d need to change 1 and 2 to 7 and 34.

Ghouls are people too!!
/bg GHOULS ARE PEOPLE TOO!!  They like buffs!!  <3 you much!!  My pet counts as a Rogue for buffs and is named %t!!  TY

• Target your ghoul at the beginning of your BG and press this.  This has gotten people to buff my pet before when they hadn’t.

Random Mounts.
/castrandom [flyable] FlyingMount1, Flyingmount2, FlyingMount3
/castrandom GroundMount1, GroundMount2, GroundMount3
/dismount

• Makes you mount up randomly.  Changing the numbers (or adding more) may be necessary for players with tons of mounts.

Mice always find the cheese.
/focus [target=mouseover]

• Whatever target you have “moused over” becomes your Focus target.

Mice find the cheese, but so do humans!!
/focus [target=mouseover,exists][exists]
/stopmacro [target=mouseover,exists][exists]
/clearfocus

• Makes whomever you’ve currently “moused over” your Focus target.
• If you have no mouse over target, then your current target becomes the Focus.
• If no target exists and you are not mousing over anything, then it will clear your Focus.

Totem Stomper!!
/petattack [target=Healing]
/petattack [target=Mana]
/petattack [target=Earthbind]
/petattack [target=Tremor]
/petattack [target=Grounding]
/petattack [target=Cleansing]

• This is supposed to go kill totems (with your ghoul) in a priority of bottom to top.  I’ve had issues with it though.  If you know an improved one tell me.

Totem Stomper 2.0
/petattack
/petattack [target=mouseover]

• Makes you pet attack your current target.
• Makes your pet attack your current mouse over target.
• It should be noted this can be used to also have your pet attack targets besides just totems.

Quit molesting Gravelraper!!
#showtooltip Huddle
/cast Huddle

• Makes your pet cast Huddle for reduced inc damage.

Editing Macros

A lot of the macros above were not just taken from somewhere else (though some were).

I used my brain matter before Brainchomper got near me!  Taking examples from other macros to make new ones is easy to do.

If you pay attention to the commands you will start to notice which commands can be altered on macros to make them work in different ways, with different abilities.

Feel free to explore and test new ideas!!  I encourage it! 

More Macros!!

Do you have a good macro not listed here?  Post a comment and we’ll see about including it!

Also if any macros give you issues, or don’t work, post a comment.  I’ll figure out if it’s broken and get a fixed one up if necessary.

-Suffer Well Brothers and Sisters…

Tags: Macros